// import the classes and interfaces for the project
 import com.lo9ic.*;

  // create the scene movie clip and center it on the stage
 var mySceneClip:MovieClip = createEmptyMovieClip("SceneMC", 1);
  mySceneClip._x = 275;
  mySceneClip._y = 200;
  mySceneClip._yscale = mySceneClip._xscale = 250;

  // create an instance of the Scene class and set 
// the clip and projection factor properties
 var myScene:Scene = new Scene();
  myScene.clip = mySceneClip;
  myScene.f = 200;

  // create style objects to be used by lines and polygons
 var bodyStyle:Style = new Style();
  bodyStyle.fillcolor = "0x660000";
  bodyStyle.linecolor = "0x660000";

   var grillStyle:Style = new Style();
  grillStyle.fillcolor = "0x666666"; 
 grillStyle.linealpha = 0;

  var windowStyle:Style = new Style(); 
 windowStyle.fillcolor = "0x000033"; 
 windowStyle.fillalpha = 20;
  windowStyle.linecolor = "0x660000";
  windowStyle.linealpha = 100;
  windowStyle.lineweight = 2;

   var antennaStyle:Style = new Style();

  var roofStyle:Style = new Style();

  var interiorStyle:Style = new Style();
  interiorStyle.fillcolor = "0x5F453A";
  interiorStyle.linealpha = 0;

   var tireStyle:Style = new Style();
  tireStyle.fillcolor = "0x333333";
  tireStyle.linealpha = 0;

  // body panels, grill and trunk nodes 
var n0:Node = new Node(-47,20,0);
 var n1:Node = new Node(-50,20,15); 
var n2:Node = new Node(50,20,15); 
var n3:Node = new Node(47,20,0);

  var n4:Node = new Node(-47,-20,0);
 var n5:Node = new Node(-50,-20,15);
 var n6:Node = new Node(50,-20,15);
 var n7:Node = new Node(47,-20,0);

  // window, hood and trunk lid nodes
 var n8:Node = new Node(-22,-20,15);
 var n9:Node = new Node(-22,20,15);
 var n10:Node = new Node(15,20,15);
 var n11:Node = new Node(15,-20,15);

  // roof nods
 var n12:Node = new Node(14,17,30);
 var n13:Node = new Node(-12,17,30);
 var n14:Node = new Node(-12,-17,30); 
var n15:Node = new Node(14,-17,30);

  // the antenna nodes
 var n16:Node = new Node(23,20,15);
 var n17:Node = new Node(23,20,35);

  // the wheel nodes
 var n18:Node = new Node(20,20,0);
 var n19:Node = new Node(20,20,-10);
 var n20:Node = new Node(30,20,-10);
 var n21:Node = new Node(40,20,-10); 
var n22:Node = new Node(40,20,0);
 var n23:Node = new Node(20,-20,0);
 var n24:Node = new Node(20,-20,-10);
 var n25:Node = new Node(30,-20,-10);
 var n26:Node = new Node(40,-20,-10); 
var n27:Node = new Node(40,-20,0);
 var n28:Node = new Node(-20,20,0);
 var n29:Node = new Node(-20,20,-10);
 var n30:Node = new Node(-30,20,-10);
 var n31:Node = new Node(-40,20,-10);
 var n32:Node = new Node(-40,20,0);
 var n33:Node = new Node(-20,-20,0);
 var n34:Node = new Node(-20,-20,-10);
 var n35:Node = new Node(-30,-20,-10);
 var n36:Node = new Node(-40,-20,-10); 
var n37:Node = new Node(-40,-20,0);

  // add the nodes to the scene
 for (var i:Number = 0; i<38; i++) {
  myScene.addNode(this["n"+i]);
 }

  // create movie clips for the body panels, windows and antenna
 var clip:MovieClip;
 for (var i:Number = 0; i<17; i++) { 
  this["clip"+i] = mySceneClip.createEmptyMovieClip("mc"+i, i+1);
 }

  // create polygons for the body panels and windows, 
// set the clip properties
 // and add the polygons to the scene
 var poly:Polygon;
 for (var i:Number = 0; i<16; i++) {
  this["poly"+i] = new Polygon();
  this["poly"+i].clip = this["clip"+i];
  myScene.addObject(this["poly"+i]);
 }

  // apply the bodystyle to the body panels
 for (var i:Number = 0; i<5; i++) {
  this["poly"+i].style = bodyStyle;
 }

  // apply the grillstyle to the grill
 this["poly5"].style = grillStyle;

  // apply the roof style to the roof
 this["poly6"].style = roofStyle;

  // apply the window style to the windows
 for (var i:Number = 7; i<11; i++) {
  this["poly"+i].style = windowStyle;
 }

  // apply the interior style to the interior
 this["poly11"].style = interiorStyle;

  // apply the tire style to the tires
 for (var i:Number = 12; i<16; i++) {
  this["poly"+i].style = tireStyle;
 }

  // add the nodes to the polygons
 // right body panel
 poly0.addNode(n0); poly0.addNode(n1); 
poly0.addNode(n2); poly0.addNode(n3);
  // left body panel
 poly1.addNode(n4); poly1.addNode(n5); 
poly1.addNode(n6); poly1.addNode(n7);

  // trunk panel
 poly2.addNode(n0); poly2.addNode(n1);
poly2.addNode(n5); poly2.addNode(n4);
 
 // trunk
 poly3.addNode(n1); poly3.addNode(n4); 
poly3.addNode(n8); poly3.addNode(n9);

  // hood
 poly4.addNode(n11); poly4.addNode(n6); 
poly4.addNode(n2); poly4.addNode(n10);

  // grill
 poly5.addNode(n2); poly5.addNode(n3); 
poly5.addNode(n7); poly5.addNode(n6);

  // roof
 poly6.addNode(n12); poly6.addNode(n13); 
poly6.addNode(n14); poly6.addNode(n15);

  // windows
 poly7.addNode(n9); poly7.addNode(n10); 
poly7.addNode(n12); poly7.addNode(n13); 
poly8.addNode(n8); poly8.addNode(n11); 
poly8.addNode(n15); poly8.addNode(n14);
 poly9.addNode(n8); poly9.addNode(n9); 
poly9.addNode(n13); poly9.addNode(n14);
 poly10.addNode(n11); poly10.addNode(n10); 
poly10.addNode(n12); poly10.addNode(n15);

  // tires
 poly12.addNode(n18); poly12.addNode(n19, true); 
poly12.addNode(n20); poly12.addNode(n21, true); 
poly12.addNode(n22);
 poly13.addNode(n23); poly13.addNode(n24, true); 
poly13.addNode(n25); poly13.addNode(n26, true); 
poly13.addNode(n27);
 poly14.addNode(n28); poly14.addNode(n29, true); 
poly14.addNode(n30); poly14.addNode(n31, true); 
poly14.addNode(n32);
 poly15.addNode(n33); poly15.addNode(n34, true); 
poly15.addNode(n35); poly15.addNode(n36, true); 
poly15.addNode(n37);

  // interior 
poly11.addNode(n8); poly11.addNode(n9); 
poly11.addNode(n10); poly11.addNode(n11);

  // create a line for the antenna 
// and add the line to the scene
 var antenna = new Line(n16, n17);
 antenna.clip = this["clip16"];
 antenna.style = antennaStyle; 
myScene.addObject(antenna);

    // create quaternion for rotating the car into initial position
 var myQuat:Quaternion = new Quaternion(); 
myQuat.fromAxisAngle(1,0,0,-Math.PI/4);
 myScene.quaternion.concat(myQuat);

  // set the axis and angle of the quaternion, concatenate it with
 // the existing quaternion, and draw the scene
 function run():Void {
  x = Math.sin(getTimer()/5000);
  y = Math.cos(getTimer()/5000);
  myQuat.fromAxisAngle(0,1,3,.1);
  myScene.quaternion.concat(myQuat); 
 myScene.draw();
 }

  // set an interval to rotate and draw the scene
 var id:Number = setInterval(run, 20);

  

interface com.lo9ic.Drawable {
  function draw():Void;
 } 

class com.lo9ic.Style {
 private var $linealpha, $lineweight, $fillalpha : Number;
 private var $linecolor, $fillcolor : String;

   function Style() {
     $lineweight = 0;
     $linealpha = 100; $fillalpha = 100;
     $linecolor = "0x000000"; $fillcolor = "0x000000";
 }

   public function set linealpha(a:Number):Void {
     $linealpha = a;
 }

   public function set lineweight(a:Number):Void {
     $lineweight = a;
 }

   public function set linecolor(a:String):Void {
  $linecolor = a;
 }

   public function set fillalpha(a:Number):Void {
  $fillalpha = a;
 }

   public function set fillcolor(a:String):Void {
  $fillcolor = a;
   }

   public function get linealpha():Number {
  return $linealpha;
 }

   public function get lineweight():Number {
  return $lineweight; 
}

   public function get linecolor():String {
  return $linecolor;
 }
   public function get fillalpha():Number {
  return $fillalpha;
 }

   public function get fillcolor():String {
  return $fillcolor; 
  } 
}  

import com.lo9ic.Quaternion;

  class com.lo9ic.Node {
   private var $x, $y, $z, $xp, $yp, $zp:Number;
   private var $q1, $q2, $q3:Quaternion;

     function Node(a:Number, b:Number, c:Number) {
  $x = a ? a : 0; $xp = $x; 
   $y = b ? b : 0; $yp = $y;
  $z = c ? c : 0; $zp = $z;
 }

     public function get x():Number {
  return $xp;
 }

     public function get y():Number {
  return $yp;
 }

     public function get z():Number {
  return $zp;
 }

     public function set x(a:Number):Void {
  $x = a;
 }

     public function set y(a:Number) :Void {
  $y = a;
 }

     public function set z(a:Number):Void{
  $z = a;
 }

    public function rotate(q:Quaternion):Void {
  $q1 = q.copy();
  $q1.invert();
  $q2 = new Quaternion();
  $q2.fromPoint($x, $y, $z);
  $q3 = q.copy();
  $q2.concat($q1);
  $q3.concat($q2);
  $xp = $q3.x;
  $yp = $q3.y; 
 $zp = $q3.z;
 }

     public function project(a:Number):Void {
   $xp = a*$xp/($zp-a); 
   $yp = a*$yp/($zp-a);
   $zp = $zp; 
  }
 } 

class com.lo9ic.Quaternion {
   private var $x, $y, $z, $w:Number;

     function Quaternion(a:Number, b:Number, c:Number, d:Number) {
  $x = a ? a : 0;
  $y = b ? b : 0;
  $z = c ? c : 0;
  $w = d ? d : 1; 
}

     public function get x():Number {
  return $x;
 }

     public function get y():Number {
  return $y;
 }

     public function get z():Number {
  return $z;

 }
    public function get w():Number {
  return $w; 
}

  public function fromPoint(a:Number, b:Number, c:Number):Void 
{
  $x = a;
  $y = b;
 
 $z = c;
  $w = 0;
 }

      public function fromAxisAngle(a:Number, b:Number, 
c:Number, d:Number):Void 
{
  var ca = Math.cos(d/2); var sa = Math.sin(d/2);
  var m = Math.sqrt(a*a + b*b + c*c);
  $x = a/m * sa;
  $y = b/m * sa;
  $z = c/m * sa;
  $w = ca;
 }

      public function concat(q:Quaternion):Void 
{
  var w1 = $w; var x1 = $x; var y1 = $y; 
var z1 = $z;
  var w2 = q.w; var x2 = q.x; var y2 = q.y; 
var z2 = q.z;
  $w = w1*w2 - x1*x2 - y1*y2 - z1*z2
  $x = w1*x2 + x1*w2 + y1*z2 - z1*y2
  $y = w1*y2 + y1*w2 + z1*x2 - x1*z2
  $z = w1*z2 + z1*w2 + x1*y2 - y1*x2
 }

     public function invert():Void {
  $x = -$x;
  $y = -$y;
  $z = -$z;
 }

    public function copy():Quaternion { 
 return new Quaternion($x, $y, $z, $w); 
  }
 } 

import com.lo9ic.Node;
 import com.lo9ic.Style;
 import com.lo9ic.Drawable;

  class com.lo9ic.Line implements Drawable {
  private var $startnode, $endnode:Node;
  private var $style:Style;
  private var $clip:MovieClip;

   function Line(a:Node, b:Node) {
   $startnode = a ? a : new Node();
   $endnode = b ? b : new Node();
   $style = new Style();


  } 
  public function set startnode(a:Node):Void {
   $startnode = a; 
 }

   public function set endnode(a:Node):Void { 
  $endnode = a; 
 }  

 public function get startnode():Node {
   return $startnode; 
 }

   public function get endnode():Node {
   return $endnode; 
  } 

   public function set style(a:Style):Void {
   $style = a ? a:$style; 
 }

    public function get style():Style { 
  return $style; 
 } 

  public function set clip(a:MovieClip):Void {
   $clip = a; 

 } 

  public function draw():Void {
   $clip.clear();
   $clip.moveTo($startnode.x, $startnode.y);
   $clip.lineStyle($style.lineweight, 
    $style.linecolor, $style.linealpha);
   $clip.lineTo($endnode.x, $endnode.y);
   $clip.swapDepths(10000+($endnode.z+$startnode.z)/2);
  } 
} 

import com.lo9ic.Node;
 import com.lo9ic.Style;
 import com.lo9ic.Line;
 import com.lo9ic.Drawable;

  class com.lo9ic.Curve extends Line implements Drawable {
  private var $controlnode : Node;

    function Curve(a:Node, b:Node, c:Node) {
   $startnode = a ? a : new Node();
   $endnode = b ? b : new Node();

   $controlnode = c ? c : new Node();
  }

    public function set controlnode(a:Node):Void {
   $controlnode = a;
  }

    public function get controlnode():Node {
   return $controlnode;
  }

   public function draw():Void {
   $clip.clear();
   $clip.moveTo($startnode.x, $startnode.y); 
  $clip.lineStyle($style.lineweight,  
    $style.linecolor, $style.linealpha);
   $clip.curveTo($controlnode.x, 
     $controlnode.y, $endnode.x, $endnode.y);
   $clip.swapDepths(10000+($endnode.z+$startnode.z+
     $controlnode.z)/3);
  }
 } 

import com.lo9ic.Drawable;
 import com.lo9ic.Node;
 import com.lo9ic.Style; 

 class com.lo9ic.Polygon implements Drawable {
  private var $nodes:Array; 
 private var $style:Style;
  private var $clip:MovieClip;
  private var $i, $j, $z:Number;    function Polygon() {
   $nodes = new Array();
   $style = new Style();
  }
    public function addNode(a:Node, b:Boolean) {
   $nodes.push({node:a, control:b}); 
 }
   public function set style(a:Style):Void {
   $style = a ? a:$style;
  }

    public function get style():Style {
   return $style; 
 }

    public function set clip(a:MovieClip):Void {
   $clip = a;
  }

    public function draw():Void {
   $i = 1;
   $j = 1;
   $z = 0;
   $clip.clear();
   $clip.moveTo($nodes[0].node.x, $nodes[0].node.y);
   $clip.lineStyle($style.lineweight, 
    $style.linecolor, $style.linealpha);
   $clip.beginFill($style.fillcolor, $style.fillalpha);
   while( $i <= $nodes.length) {
    $j = $i%$nodes.length;
    if(!$nodes[$j].control && !$nodes[$i-1].control) {
     $clip.lineTo($nodes[$j].node.x, $nodes[$j].node.y);
    } else if ($nodes[$i-1].control) {
     $clip.curveTo($nodes[$i-1].node.x, 
      $nodes[$i-1].node.y, $nodes[$j].node.x, 
      $nodes[$j].node.y);
    }
    $z += $nodes[$j].node.z;
    $i++;
   }
   $clip.endFill();
   $clip.swapDepths(10000+$z/$nodes.length);
  } 
} 

import com.lo9ic.Style; 
import com.lo9ic.Quaternion;
 import com.lo9ic.Node;
 import com.lo9ic.Drawable;

  class com.lo9ic.Scene implements Drawable {
  private var $f:Number;
  private var $nodes:Array;
  private var $objects:Array;
  private var $quaternion:Quaternion;
  private var $clip:MovieClip;
  private var $i:Number; 

  function Scene() {
   $f = 300;
   $nodes = new Array();
   $objects = new Array();
   $quaternion = new Quaternion();
  }

    public function get f():Number {
   return $f; 
 } 

   public function set f(a:Number):Void {
   $f = a; 
 }   

  public function set quaternion(a:Quaternion):Void {
   $quaternion = a;
  } 

   public function get quaternion():Quaternion {
   return $quaternion; 
 }

    public function set clip(a:MovieClip):Void {
   $clip = a;
  }   

 public function get clip():MovieClip {
   return $clip; 
 } 

   public function addNode(a:Node):Void {
   $nodes.push(a); 
 }

    public function addObject(a:Drawable):Void {
   $objects.push(a);
  }

    public function draw():Void {
   $i = 0;
   while($i<$nodes.length) {
    $nodes[$i].rotate($quaternion);
    $nodes[$i].project($f);
    $i++; 
  }
   $i = 0;
   while($i<$objects.length) {
    $objects[$i].draw();
    $i++;
   } 
  }
 }